# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Provides mechanisms for walking through any arbitrary PHP variable"
HOMEPAGE="https://github.com/symfony/var-dumper"
SRC_URI="https://github.com/symfony/var-dumper/archive/v${PV}.tar.gz -> ${P}.tar.gz"

S="${WORKDIR}/var-dumper-${PV}"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"

BDEPEND="dev-php/theseer-Autoload"

RDEPEND="
	>=dev-lang/php-8.2:*
	dev-php/fedora-autoloader
	dev-php/symfony-deprecation-contracts
	dev-php/symfony-polyfill-mbstring
"

src_prepare() {
	default

	phpab \
		--quiet \
		--output autoload.php \
		--template fedora2 \
		--basedir . \
		. \
		|| die

	VENDOR_DIR="${EPREFIX}/usr/share/php"
	cat >> autoload.php <<EOF || die "failed to extend autoload.php"

// Dependencies
\Fedora\Autoloader\Dependencies::required([
	"${VENDOR_DIR}/Fedora/Autoloader/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/DeprecationContracts/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Mbstring/autoload.php"
]);
EOF
	echo "require_once __DIR__ . \"/Resources/functions/dump.php\";" >> autoload.php

}

src_install() {
	insinto "/usr/share/php/Symfony/Component/VarDumper"
	doins -r *.php Caster Cloner Command Dumper Exception LICENSE Resources Server Test

	exeinto "/usr/share/php/Symfony/Component/VarDumper/bin"
	doexe "Resources/bin/var-dump-server"
	dosym "/usr/share/php/Symfony/Component/VarDumper/bin/var-dump-server" "/usr/bin/var-dump-server"
}