# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Object-Relational-Mapper for PHP"
HOMEPAGE="https://github.com/doctrine/orm"
SRC_URI="https://github.com/doctrine/orm/archive/${PV}.tar.gz -> ${P}.tar.gz"

S="${WORKDIR}/orm-${PV}"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"

BDEPEND="dev-php/theseer-Autoload"

RDEPEND="
	>=dev-lang/php-7.4:*
	dev-php/fedora-autoloader
	dev-php/composer-runtime-api
	dev-php/doctrine-collections
	dev-php/doctrine-dbal
	dev-php/doctrine-deprecations
	dev-php/doctrine-event-manager
	dev-php/doctrine-inflector
	dev-php/doctrine-instantiator
	dev-php/doctrine-lexer
	dev-php/doctrine-persistence
	dev-php/psr-cache
	dev-php/symfony-console
	dev-php/symfony-var-exporter
"

src_prepare() {
	default

	phpab \
		--quiet \
		--output autoload.php \
		--template fedora2 \
		--basedir src \
		src \
		|| die

	VENDOR_DIR="${EPREFIX}/usr/share/php"
	cat >> autoload.php <<EOF || die "failed to extend autoload.php"

// Dependencies
\Fedora\Autoloader\Dependencies::required([
	"${VENDOR_DIR}/Fedora/Autoloader/autoload.php",
	"${VENDOR_DIR}/Doctrine/Common/Collections/autoload.php",
	"${VENDOR_DIR}/Doctrine/DBAL/autoload.php",
	"${VENDOR_DIR}/Doctrine/Deprecations/autoload.php",
	"${VENDOR_DIR}/Doctrine/Common/autoload.php",
	"${VENDOR_DIR}/Doctrine/Inflector/autoload.php",
	"${VENDOR_DIR}/Doctrine/Instantiator/autoload.php",
	"${VENDOR_DIR}/Doctrine/Common/Lexer/autoload.php",
	"${VENDOR_DIR}/Doctrine/Persistence/autoload.php",
	"${VENDOR_DIR}/Psr/Cache/autoload.php",
	"${VENDOR_DIR}/Psr/Container/autoload.php",
	"${VENDOR_DIR}/Psr/Log/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/Console/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/DeprecationContracts/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Ctype/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Intl/Grapheme/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Intl/Normalizer/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Mbstring/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Php84/autoload.php",
	"${VENDOR_DIR}/Symfony/Contracts/Service/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/String/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/VarExporter/autoload.php"
]);
EOF
}

src_install() {
	insinto "/usr/share/php/Doctrine/ORM"
	doins -r *.php LICENSE src/*
}