# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="PHP WebSocket library"
HOMEPAGE="https://github.com/ratchetphp/Ratchet"
SRC_URI="https://github.com/ratchetphp/Ratchet/archive/v${PV}.tar.gz -> ${P}.tar.gz"

S="${WORKDIR}/Ratchet-${PV}"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"

BDEPEND="dev-php/theseer-Autoload"

RDEPEND="
	>=dev-lang/php-7.4:*
	dev-php/fedora-autoloader
	dev-php/guzzlehttp-psr7
	dev-php/ratchet-rfc6455
	dev-php/react-event-loop
	dev-php/react-socket
	dev-php/symfony-http-foundation
	dev-php/symfony-routing
"

src_prepare() {
	default

	phpab \
		--quiet \
		--output autoload.php \
		--template fedora2 \
		--basedir . \
		. \
		|| die

	VENDOR_DIR="${EPREFIX}/usr/share/php"
	cat >> autoload.php <<EOF || die "failed to extend autoload.php"

// Dependencies
\Fedora\Autoloader\Dependencies::required([
	"${VENDOR_DIR}/Fedora/Autoloader/autoload.php",
	"${VENDOR_DIR}/Evenement/autoload.php",
	"${VENDOR_DIR}/GuzzleHttp/Psr7/autoload.php",
	"${VENDOR_DIR}/Psr/Http/Message/autoload.php",
	"${VENDOR_DIR}/Psr/Http/Message/autoload.php",
	"${VENDOR_DIR}/Ralouphie-getallheaders/autoload.php",
	"${VENDOR_DIR}/Ratchet/RFC6455/autoload.php",
	"${VENDOR_DIR}/React/Cache/autoload.php",
	"${VENDOR_DIR}/React/Dns/autoload.php",
	"${VENDOR_DIR}/React/EventLoop/autoload.php",
	"${VENDOR_DIR}/React/Promise/autoload.php",
	"${VENDOR_DIR}/React/Socket/autoload.php",
	"${VENDOR_DIR}/React/Stream/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/DeprecationContracts/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/HttpFoundation/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Mbstring/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Php83/autoload.php",
	"${VENDOR_DIR}/Symfony/Component/Routing/autoload.php"
]);
EOF
}

src_install() {
	insinto "/usr/share/php/Ratchet"
	doins -r *.php LICENSE src tests
}