# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="PHP Doctrine Collections library that adds additional functionality on top of PHP arrays."
HOMEPAGE="https://github.com/doctrine/collections"
SRC_URI="https://github.com/doctrine/collections/archive/${PV}.tar.gz -> ${P}.tar.gz"

S="${WORKDIR}/collections-${PV}"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"

BDEPEND="dev-php/theseer-Autoload"

RDEPEND="
	>=dev-lang/php-7.4:*
	dev-php/fedora-autoloader
	dev-php/doctrine-deprecations
	dev-php/symfony-polyfill-php84
"

src_prepare() {
	default

	phpab \
		--quiet \
		--output autoload.php \
		--template fedora2 \
		--basedir src \
		src \
		|| die

	VENDOR_DIR="${EPREFIX}/usr/share/php"
	cat >> autoload.php <<EOF || die "failed to extend autoload.php"

// Dependencies
\Fedora\Autoloader\Dependencies::required([
	"${VENDOR_DIR}/Fedora/Autoloader/autoload.php",
	"${VENDOR_DIR}/Doctrine/Deprecations/autoload.php",
	"${VENDOR_DIR}/Symfony/Polyfill/Php84/autoload.php"
]);
EOF
}

src_install() {
	insinto "/usr/share/php/Doctrine/Common/Collections"
	doins -r *.php LICENSE docs src/*
}