New flexget

2020-02-13 21:57:33 +01:00
parent 4f9689ee8c
commit df8d00dc33
28 changed files with 573 additions and 20 deletions
@@ -0,0 +1,3 @@
+DIST Sphinx-2.0.1.tar.gz 6017030 BLAKE2B a446aab8c7f5a4adc93477f4f60ca975690cb4c507d6e51393a4b2c4c56563b9a12e3ea3f85d214c6bdbc7834be107384fe9029d09a73da207fd9699c4b77ab8 SHA512 28430912917a8e3eb6efe6b69268e2a5ae06795c261f2a18ef62f781e365396832c4e4bcfaad7704b1c5f840e98a9dfb82e3b438a491a13cea5c10bee66bf23b
+EBUILD sphinx-2.0.1.ebuild 3479 BLAKE2B b2290a7f1abe1f08960f73b3ff8069bae7aaa5e9f73b29c1d7052531aa8c36b60e32d0eeec72f4c7eff5e866f5452ba6ccaab1d159f2ed6ea919838f16bfb6db SHA512 6fa5238ed37574221640aee81dd2c5bab1ac5efea754c5bfbf183aa7cb80f2653f1f9f628d1d91888e5c7aacf5a4aeb75ad6315d2866f4b0fc461f4519137e60
+MISC metadata.xml 556 BLAKE2B a2689efbe3d569fa878296875f4145fdb4d83b4c4821aa636d4006b1823e5646b9cebd5341b4bc02de30985191b83461363cc892aca638e678f86a6e314dcef3 SHA512 bff6813bf9c5110c2e4f5764f911309325923cb58300c19c079d1e6de3d6c4c0bcaf4e206fa4bc11ebf54b961c7e09217310b5647029350d4f9602da6325db0c
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<longdescription lang="en">Sphinx is a tool to create documentation for Python projects (or other documents consisting of multiple reStructuredText sources).</longdescription>
+	<upstream>
+		<remote-id type="pypi">Sphinx</remote-id>
+	</upstream>
+	<use>
+		<flag name="net">enable internet capabilities</flag>
+	</use>
+</pkgmetadata>
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_6,3_7,3_8} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="http://www.sphinx-doc.org/"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc latex test"
+
+# Tests automagically use latex, bug 667414
+#REQUIRED_USE="test? ( latex )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/snowballstemmer[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-htmlhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+
+S="${WORKDIR}/${P^}"
+
+python_prepare_all() {
+	# remove tests that fail due to network-sandbox
+	rm tests/test_build_linkcheck.py || die "Failed to remove web tests"
+	sed -i -e 's:test_latex_images:_&:' tests/test_build_latex.py || die
+	sed -i -e 's:test_latex_doc:_&:' tests/test_build_latex.py || die
+
+	# requires specific locales
+	sed -i -e 's:test_babel_with_language_:_&:' tests/test_build_latex.py || die
+	sed -i -e 's:test_polyglossia_with_language_:_&:' tests/test_build_latex.py || die
+
+	# fail for unknown reasons. TODO: find out why
+	sed -i -e 's:test_build_latex_doc:_&:' tests/test_build_latex.py || die
+	rm tests/test_ext_imgconverter.py || die "Failed to remove broken test"
+
+	# fails when additional sphinx themes are installed
+	sed -i -e 's:test_theme_api:_&:' tests/test_theming.py || die
+
+	# fail under pypy3
+	sed -i -e 's:test_partialmethod:_&:' tests/test_autodoc.py || die
+	sed -i -e 's:test_partialfunction:_&:' tests/test_autodoc.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+	popd >/dev/null || die
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}