Added f3 flash fraud detection tool

2022-09-05 11:21:09 +02:00
parent 6465bb877c
commit b722f6b0a1
17 changed files with 108 additions and 337 deletions
@@ -0,0 +1,2 @@
+EBUILD f3-9999.ebuild 1132 BLAKE2B 6cf42b66692483cb9fbe00b594e51aba5bade950084d648508d51665332dc34a4033cbbcc9aa182e3054e3c5b19fd9ec3b38b5940afc4d20467ededb375558b0 SHA512 d112f42e55b3f33c7d459a0842ac2097dea3043a173db5ad5ee9ce3701012e9fd1cbba3aa5925cbed081971c534c1e7312231d84a09c73ccca5ada74f003b745
+MISC metadata.xml 876 BLAKE2B f8cfda7a892bfe6221780f072eabdd89724dfb5752557a157cfd1245dc52262ee03f5c749fd660f7d0ec514d631946c13dcce4153ae3bdcefaa7b7d93193d00c SHA512 d19e16a5d242a33af6a821e33c81f2aab3a361e0cf721915740c3f14d45bfa705d23490d44131d4e28d11e0930a5fbb334b738660b5bbe7a48264a2d5523638c
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Utilities to detect broken or counterfeit flash storage"
+HOMEPAGE="http://oss.digirati.com.br/f3/ https://github.com/AltraMayor/f3"
+
+PATCHES=(
+)
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/AltraMayor/${PN}.git"
+
+	PATCHES=()
+
+	inherit git-r3
+else
+	SRC_URI="https://github.com/AltraMayor/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~arm ~arm64 x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+IUSE="extra"
+
+RDEPEND="elibc_musl? ( sys-libs/argp-standalone )"
+DEPEND="${RDEPEND}
+	extra? (
+		sys-block/parted
+		virtual/udev
+	)"
+
+DOCS=( changelog README.rst )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's:-ggdb::' \
+		-e 's:^PREFIX =:PREFIX ?=:' \
+		Makefile || die
+
+	# bug #715518
+	use elibc_musl && append-ldflags -largp
+
+	tc-export CC
+}
+
+src_compile() {
+	default
+
+	if use extra; then
+		emake V=1 extra
+	fi
+}
+
+src_install() {
+	emake PREFIX="${ED}/usr" install
+
+	if use extra; then
+		emake PREFIX="${ED}/usr" install-extra
+	fi
+
+	einstalldocs
+}
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<longdescription lang="en">
+		F3 - an alternative to h2testw
+
+		The "Fight Flash Fraud" or "Fight Fake Flash" tool represents
+		a GPLv3 implementation of the algorithm of h2testw and further
+		improvements to speed up the identification of fake drives
+		as well as making them usable.
+
+		You can also use these utilities if you want to test the
+		integrity of your USB/flash medium.
+	</longdescription>
+	<upstream>
+		<bugs-to>https://github.com/AltraMayor/f3/issues</bugs-to>
+		<remote-id type="github">AltraMayor/f3</remote-id>
+	</upstream>
+	<use>
+		<flag name="extra">Build the additional f3probe, f3brew and f3fix utility (requires <pkg>sys-block/parted</pkg> and <pkg>virtual/udev</pkg>)</flag>
+	</use>
+</pkgmetadata>