Updates

2023-06-30 09:14:33 +02:00
parent be3f1a6c77
commit a5e9df0216
6 changed files with 165 additions and 0 deletions
@@ -0,0 +1,3 @@
+DIST pstoedit-3.78.tar.gz 1301408 BLAKE2B 8a8cc64ac28554360654f3cd87a468f4925edf6e5ef14fa5c618571479f8a317082f88cf91bf0e48cd49a4858cb5e0949798bf37361fefc523efd61b2af8957e SHA512 ed880da1ba16780224b4bb40d520f99bc5290b4335dd30f1a195855ce75b3880d5a4fca9885b214855ce61d8bd701aa0681a190e69a8fdef2f3d5e1e2f692648
+EBUILD pstoedit-3.78.ebuild 1256 BLAKE2B 6d4c6fb52b3606b500f6bd0b162e5a2de8b13d70bcbddcaa071f7e437d0ec66fff283335e84fa8a8be46dc26d87369c278235c7635e785d5aef9ac375f644bb9 SHA512 d37877dae32ea46bc268a6a64dd2582ed16a9e39ab76aa9fe6088d4c08f97b9a4c5d74bac1d255628c6fe774568d5cc982f345264141cd29a8c09200b10014cc
+MISC metadata.xml 634 BLAKE2B ea6bd21397a45a3591572e803513b32361761a9872800027ab779c2a9f0e214db9e70dc9fed0acbf6dafe3769cd8525e21d2875e62f4b8711bfc03f38bc47214 SHA512 d8d509f442aee8fbb9036dab15fba870e18b8d6b0b120d3c82bb50e7d86379425f5b91161e4f37137f43710fd50ac2c8481b47b0dd5ab39654729a7280258465
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>tex@gentoo.org</email>
+    <name>Gentoo TeX Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>printing@gentoo.org</email>
+    <name>Gentoo Printing Project</name>
+  </maintainer>
+  <use>
+    <flag name="emf">Enable <pkg>media-libs/libemf</pkg> support</flag>
+    <flag name="pptx">Enable support for generating PowerPoint pptx files</flag>
+  </use>
+  <upstream>
+    <remote-id type="sourceforge">pstoedit</remote-id>
+  </upstream>
+</pkgmetadata>
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Translate PostScript and PDF graphics into other vector formats"
+HOMEPAGE="https://sourceforge.net/projects/pstoedit/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
+IUSE="emf imagemagick plotutils pptx"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=app-text/ghostscript-gpl-8.71-r1
+	>=media-libs/gd-2.0.35-r1:=
+	emf? ( >=media-libs/libemf-1.0.3 )
+	imagemagick? ( >=media-gfx/imagemagick-6.6.1.2:=[cxx] )
+	plotutils? ( media-libs/plotutils )
+	pptx? ( dev-libs/libzip:= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( doc/readme.txt )
+HTML_DOCS=( doc/{changelog,pstoedit}.htm )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/CXXFLAGS="-g"/d' \
+		-e 's:-pedantic::' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--without-swf
+		$(use_with emf)
+		$(use_with imagemagick magick)
+		$(use_with plotutils libplot)
+		$(use_with pptx)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	doman doc/pstoedit.1
+
+	find "${ED}" -name '*.la' -delete || die
+}