diff --git a/app-portage/layman/Manifest b/app-portage/layman/Manifest
new file mode 100644
index 0000000..bb5f60a
--- /dev/null
+++ b/app-portage/layman/Manifest
@@ -0,0 +1,2 @@
+DIST layman-2.4.3.tar.gz 135311 BLAKE2B b83fd543468be904a10d6fbda11f8d603a6936ecef3029c9d1c82fe4c938d2cd299874a3e114ac3524485ce8a33c5ec21885adddc218f5e331519318c0b1ad5a SHA512 2f3d1180647b358d5ca929fd28c6c5f4664f1f6f24e3114a4dc886d23279ffcdde7ca292c64aab84f1710ddf7029c26483de07c2271ca527b8618888b0ea2b54
+EBUILD layman-2.4.3.ebuild 2196 BLAKE2B 0b7c2225e4e3dbe45588299e5b50b2751a0769d16922bf03a1f2bdc29fad6692d5dbd1d84e91eb9dfd4c0e58d21e54991af6d87581f64e40fb537faa8b950ad3 SHA512 14b314ca30dcc191d6ff1d5021343881ed24fcea4d5e151490e481f87e592c6f2cd91434e6c572bfe29eca02757bcea3d7245464f2609d519292820b0c5eae23
diff --git a/app-portage/layman/layman-2.4.3.ebuild b/app-portage/layman/layman-2.4.3.ebuild
new file mode 100644
index 0000000..c864d32
--- /dev/null
+++ b/app-portage/layman/layman-2.4.3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="xml(+),sqlite?"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 linux-info prefix
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="git://anongit.gentoo.org/proj/layman.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Layman"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="cvs darcs +git gpg g-sorcery mercurial sqlite squashfs subversion sync-plugin-portage test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-vcs/subversion )
+	"
+
+RDEPEND="
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? ( >=dev-vcs/subversion-1.5.4[http(+)] )
+	gpg? ( >=dev-python/pyGPG-0.2 )
+	sync-plugin-portage? ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	>=dev-python/ssl-fetch-0.4[${PYTHON_USEDEP}]
+	"
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all() {
+	python_setup
+	esetup.py setup_plugins
+	distutils-r1_python_prepare_all
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	suite=layman/tests/external.py
+	PYTHONPATH="." "${PYTHON}" ${suite} || die "test suite '${suite}' failed"
+	unset suite
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	docinto html
+	dodoc doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}