Updated gsconnect gnome shell extension

gnome-extra/gnome-shell-extension-gsconnect/Manifest

@@ -0,0 +1,3 @@
+DIST gnome-shell-extension-gsconnect-53.tar.gz 729500 BLAKE2B 5cb841d67ee9021b3402420104dd8f74d94c2ed50c45182aec24fd2a39a4f30bab2167192c6cd701e211c3fa12b3a92a5dc18e92867eaee5dd233f107ddf6e42 SHA512 fa2ed1755180446b7e5a203f70a8fa098771380296ceb7f72c9c862a71e0baa8c8b9d34294e6608d6dad149bb98ff9fc224fd0b37bf8f532397df6f7587102c0
+EBUILD gnome-shell-extension-gsconnect-53.ebuild 1613 BLAKE2B 256af71a27da58c575b4f32818aa1a956dca48a9aaba40be0f51d6aa38cf0d83cc6dfea30b5f0f4315c5cc1c0802046cb17176e68c266a701a67a5cf948e4db8 SHA512 91d8197acdd565c4c64ab8035c57cbd45698b9e7a4646c4c195b6ad1681526885d0011fca6e9a8f716e94f77293ed2d5d44c6130e3dad280dab78e026c25e6e9
+MISC metadata.xml 346 BLAKE2B d1e2c79cae69a58f7af962316046f4620238b88d42e0f211a28ba271633993bae4df79956ab9dde4f4e94e7e77233288657d5b3c1876c9192118a11ee5ee678f SHA512 00b2e45892280f1a042b3ec03d66c3fcc7a2b95f94534d22fb8df936976384bb78433337b339ae023ae9850f2e4c0cfb8b12fae28ae7863d2ebe93a47784a77a

gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-53.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2-utils meson readme.gentoo-r1 xdg
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.68
+	=gnome-base/gnome-shell-42*
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dinstalled_tests=false \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

gnome-extra/gnome-shell-extension-gsconnect/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>pacho@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<use>
+		<flag name="nautilus">Install Nautilus extension for sending files via GSConnect</flag>
+	</use>
+</pkgmetadata>